Datei:Mushroomcloud Size.svg
Zur Navigation springen
Zur Suche springen
Größe der PNG-Vorschau dieser SVG-Datei: 600 × 450 Pixel. Weitere aus SVG automatisch erzeugte PNG-Grafiken in verschiedenen Auflösungen: 320 × 240 Pixel | 640 × 480 Pixel | 1.024 × 768 Pixel | 1.280 × 960 Pixel | 2.560 × 1.920 Pixel
Originaldatei (SVG-Datei, Basisgröße: 600 × 450 Pixel, Dateigröße: 54 KB)
Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden.
Beschreibung
| Beschreibung |
English: Final height h and radius r of a nuclear mushroom cloud as a function of the explosive yield W. The final height is approximately the height above the burst point for low and intermediate W and approx. the height above sea leval for high W.
Quelle: Glasstone & Dolan (1977), numerical approximation of original graph.
Deutsch: Endhöhe und Radius der Pilzwolke einer Kernwaffenexplosion als Funktion der Sprengkraft W. Die Endhöhe ist ungefähr die Höhe über dem Detonationspunkt für geringe und mittlere W und ungefähr die Höhe über Meeresniveau für große W.
Quelle: Glasstone & Dolan (1977), numerische Näherung des Originalgraphen. |
| Datum | |
| Quelle | Eigenes Werk |
| Urheber | SiriusB |
| Andere Versionen | Mushroomcloud Size.png |
| SVG‑Erstellung |  Dieser Plot wurde mit Gnuplot erstellt.  Dieser Plot verwendet Text-Einbettung, die mit einem Texteditor leicht übersetzbar ist. |
The graph can be reproduced with Gnuplot (version 4.2 or higher) using this script
Quelltext
Gnuplot code
reset
lw1=2.0; lw2=2.0; lw3=1.; lw4=0.5
set term svg enhanced size 600,450 font "Helvetica, 14";set output 'cloud.svg'
ch=3.0 # scaling factor for height
cw=0.6 # scaling factor for radius
f(lx)=0.006941*lx**4-0.06216*lx**3+0.1526*lx**2+0.1878*lx # log height
g(lx)=0.0137*lx**3-0.0358*lx**2+0.37*lx # log radius
h(lx)=ch*10.**f(lx)
r(lx)=cw*10.**g(lx)
h0(lx)=ch*10.**(lx/3.)
r0(lx)=cw*10.**(lx/3.)
clx=0.75;dlx=0.2 # smooth interpolation via Fermi-Dirac function
tau(lx)=1./(exp((clx-lx)/dlx)+1.) # (other interpolations are possible)
uat(lx)=1.-tau(lx)
hsw(lx) = tau(lx)*h(lx)+uat(lx)*h0(lx)
rsw(lx) = tau(lx)*r(lx)+uat(lx)*r0(lx)
set logscale x; set logscale x2
set xrange [1:50000]; set xtics 10; set mxtics 10
set yrange [0:50]; set ytics 10; set mytics 5
set grid xtics ytics mxtics mytics back lt 1 lw 0.5 lc rgb '#808080',lt 1 lw 0.5 lc rgb '#B0B0B0'
set key left
## Use slanted fonts for variables if available
#set xlabel '{/Oblique W} / kT'; set ylabel '{/Oblique h},{/Oblique r} / km'
set xlabel 'W / kT'; set ylabel 'h, r / km'
plot hsw(log10(x)) t '{/Oblique h}' w l lt 1 lw lw1 lc rgb '#700', \
rsw(log10(x)) t '{/Oblique r}' w l lt 2 lw lw1 lc rgb '#F00'
reset
Lizenz
|
Ich, der Urheberrechtsinhaber dieses Werkes, veröffentliche es als gemeinfrei. Dies gilt weltweit. In manchen Staaten könnte dies rechtlich nicht möglich sein. Sofern dies der Fall ist: Ich gewähre jedem das bedingungslose Recht, dieses Werk für jedweden Zweck zu nutzen, es sei denn, Bedingungen sind gesetzlich erforderlich. |
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
| Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
|---|---|---|---|---|---|
| aktuell | 16:43, 21. Nov. 2008 | | 600 × 450 (54 KB) | SiriusB | {{Information |Description={{en|1=Final height h and radius r of a nuclear mushroom cloud as a function of the explosive yield W. The final height is approximately the height above the burst point for low and intermediate W and approx. the height above se |
Dateiverwendung
Die folgende Seite verwendet diese Datei:
