#!/usr/bin/gnuplot
# gnuplot 

# Variablen - die wichtigsten Paramter dieser Grafik:
# (in der Regel wird es reichen fuer eine neue Grafik dieser Werte zu ändern)
my_data               = 'Einwohnerentwicklung von Lichtenberg (Salzgitter).dat'
my_xrange_min         = '01.01.1821'
my_xrange_max         = '31.12.2017'
my_xtics_years        = '25'
my_mxtics             = '5'
my_yrange_min         = '0'
my_yrange_max         = '*'    # Nur hier ist '*' erlaubt und sinnvoll
my_ytics              = '500'
my_ymtics             = '5'



# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key                  # als Standard keine Legende
set style data lines       # wird bei 'plot' überschrieben 
set style fill transparent solid 0.4 # ebenfalls bei 'plot' überschrieben
set grid                   # Gitterlinien verwenden
set border 3               # Rahmen unten (Bit 1) und links (+ Bit 2) 


# Bereiche/Format/etc X-Achse 
set xdata time             # X-Achse als Zeitachse
set xlabel 'Jahr'          # Beschriftung X-Achse
set xlabel offset 0, 0.75  # Schrift etwas höher
set xrange [ my_xrange_min : my_xrange_max]
                           # Wertebreich der X-Achse
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * my_xtics_years
                           # xtics in Sekunden 
                           # der Beginn (Wert vor dem Komma) der X-Einteilung 
                           # kann außerhalb xrange liegen
set xtics offset  0, 0.5   # Beschriftung näher an die X-Achse
set mxtics 5               # Skalenstriche 
set xtics nomirror         # Nur unten Skalieren
set format x '%Y'          # Beschriftungsformat JJJJ
set xtics  out             # Skal. aussen damit sich nicht von Grafik 
                           # überschr. wird


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label 
# Untere Begrenzung des Bereichs der Y-Achse
set yrange [ my_yrange_min : ]
# Obere  Begrenzung des Bereichs der Y-Achse
# wir Testen ob der Wert der Var.  my_yrange_max ein '*' ist und reagieren 
# entsprechend weil der '*' sich nicht direkt via Var. setzen lässt. 
if ( ( my_yrange_max eq '*' )) set yrange [ : *             ]
if (!( my_yrange_max eq '*' )) set yrange [ : my_yrange_max ]
set ytics my_ytics         # Anzahl der kleinen Teilstriche
set ytics offset 0.5       # Schrift etwas nach rechts
set ytics nomirror         # oben keine Teilstriche
set decimalsign locale "de_DE.UTF-8" # Stelle Input und Output auf "," um 
                           # set decimalsign ',' würde nur Output umstellen,
                           # unter Windows lautet der String "de_DE.utf8"
set format y  "%'.0f"      # Ausgabeformat
set mytics my_ymtics       # Unterscalierung 
set ytics  out             # Skal. aussen da sie sonst von Grafik 
                           # überschr. wird


#### Markierungsbalken für die beiden Weltkriege etc.
# Die set-Befehle ggf. auskommentieren
# Attribute für Markierungsbalken
set style rect fillcolor lt -1 fillstyle solid 0.1 noborder
#
# == 1. Weltkrieg
 set obj rect from '28.07.1914', graph 0 to '11.11.1918' , graph 1
 set label "1. Weltkrieg"          at '30.06.1916', graph 0.9 rotate by +60 center
# ==  2. Weltkrieg
 set obj rect from '01.09.1939', graph 0 to '04.05.1945' , graph 1
 set label "2. Weltkrieg"          at '30.06.1942', graph 0.9 rotate by +60 center
# == Dädärä
#set obj rect from '07.10.1949', graph 0 to '03.10.1990' , graph 1
#set label "DDR"                   at '01.01.1970', graph 0.9 rotate by +60 center


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg) 
# UNIX, die mit Pipes umgehen könnten, sollten hier hier das 
# folgende 'set output ...' kommentieren. 
set output 'Einwohnerentwicklung von Lichtenberg (Salzgitter).svg' 
set term svg size 800,400 font "Arial,16"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer 
# Einbindung [[Datei:Meine_Grafik.svg|mini|400px|Text]] noch Schrift/Details 
# erkennen kann. 


# Erzeugen der Ausgabe 
plot \
   my_data using 1:2 with linespoints linecolor 'dark-blue'   linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30\