BeschreibungAGK-pentacube.png	A chiral pentacube
Quelle	Povray image made by Andrew Kepert for wikipedia.
Urheber	User AndrewKepert on en.wikipedia
Genehmigung (Weiternutzung dieser Datei)	AndrewKepert aus der englischsprachigen Wikipedia, der Nutzungsrechtsinhaber dieses Werkes, veröffentlicht es hiermit unter der folgenden Lizenz: Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren; es gibt keine unveränderlichen Abschnitte, keinen vorderen und keinen hinteren Umschlagtext. Der vollständige Text der Lizenz ist im Kapitel GNU-Lizenz für freie Dokumentation verfügbar.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue Diese Datei ist unter der Creative-Commons-Lizenz „Namensnennung – Weitergabe unter gleichen Bedingungen 3.0 nicht portiert“ lizenziert. Namensnennung: AndrewKepert Dieses Werk darf von dir verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden neu zusammengestellt werden – abgewandelt und bearbeitet werden Zu den folgenden Bedingungen: Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders. Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten. Diese Lizenzmarkierung wurde auf Grund der GFDL-Lizenzaktualisierung hinzugefügt.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue
Andere Versionen	Originally from en.wikipedia; description page is (was) here * 05:32, 24 October 2005 [[:en:User:AndrewKepert|AndrewKepert]] 200×200 (17,049 bytes) <span class="comment">(Povray image made by me (AndrewKepert) for wikipedia. Source under LGPL to follow)</span>

Source

Source under LGPL below

// Povray source for a wikipedia image of a polycube
// By Andrew Kepert, October 2005
// License : LGPL

#include "colors.inc"
#declare eps=0.001;


background{White}

#declare ringn=31;
#declare ang=0;
#while (ang < 359)
    light_source {<0,0,9000> rgb .7/ringn rotate 40*x rotate ang*z}
    #declare ang=ang+360/ringn;
#end
light_source { 
    <0,0,1000> .8*White 
    area_light <100, 0, 0>, <100, 0, 5>, 7,7    
    // adaptive 1
    rotate 55*x rotate 15*z
    }

#declare r=0.05;
#declare ptA=<r,r,r>;
#declare ptB=<1-r,r,r>;
#declare ptC=<1-r,r,1-r>;
#declare ptD=<r,r,1-r>;
#declare cubiecentre=<0.5,0.5,0.5>;

#declare cubiefrag=union{
    cylinder { ptA,ptB,r }
    sphere { ptB,r }
    cylinder  { ptB,ptC,r }
    sphere { ptC,r }
    cylinder { ptC,ptD,r }
    }
#declare cubie=union{
    box { <r,r,0>,<1-r,1-r,1> }
    box { <r,r,0>,<1-r,1-r,1> translate -cubiecentre rotate 90*x translate cubiecentre}
    box { <r,r,0>,<1-r,1-r,1> translate -cubiecentre rotate 90*y translate cubiecentre}
#if(1)
    object { cubiefrag }
    object { cubiefrag translate -cubiecentre rotate 90*z translate cubiecentre }
    object { cubiefrag translate -cubiecentre rotate 180*z translate cubiecentre }
    object { cubiefrag translate -cubiecentre rotate 270*z translate cubiecentre }
#end
    }



//=================== floor
#if (1)
plane {
    z, -0.1
    pigment {checker .95*White, 1*White scale 2.5}
    finish {
        ambient .2
        diffuse .8
        }
    }
#end

union {
    object { cubie translate <0,0,0> }
    object { cubie translate <1,0,0> }
    object { cubie translate <0,1,0> }
    object { cubie translate <0,0,1> }
    object { cubie translate <0,-1,1> }
    pigment { rgb <.5,.8,1> }
    finish { phong 0.8 diffuse 0.6 ambient 0.2 }
    }
    


#if (0) // axes for draft
#declare axislength=7;
cylinder { <0,0,0>,<axislength,0,0>,0.1 texture { pigment { colour rgb <1,0,0> } finish { ambient 1 } } }
cylinder { <0,0,0>,<0,axislength,0>,0.1 texture { pigment { colour rgb <0,1,0> } finish { ambient 1 } } }
cylinder { <0,0,0>,<0,0,axislength>,0.1 texture { pigment { colour rgb <0,0,1> } finish { ambient 1 } } }
#end

//======================== camera stuff
#declare camera_elevation=25;
#declare camera_bearing=-35;
#declare camera_dist=6;
#declare camera_ratio=1/2;
camera {
    perspective
    direction -x
    right y*camera_ratio
    up z*camera_ratio
    location camera_dist*x
    rotate -camera_elevation*y  
    rotate camera_bearing*z
    translate <1,0,1>
}