#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid
set border 3               # Bit 1 (unten) + Bit 2 (links)


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['25.05.1987':'31.12.2016']
set xtics '01.01.1500', 60 * 60 * 24 * 365.25 * 5
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5
set xtics nomirror    # Nur unten Skalieren
set format x '%Y'     # Beschriftungsformat JJJJ


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl'
set yrange [1500000:2000000]
set ytics 50000
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f"  # Ausgabeformat
set mytics 5


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe für vier Graphen in vier Farben
plot \
  'daten.csv' using 1:2 with linespoints linecolor 'dark-red'     linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30,\
  'daten.csv' using 1:3 with linespoints linecolor 'dark-blue'    linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30