Datei:Frankfurt population - Prognosen.svg
Originaldatei (SVG-Datei, Basisgröße: 800 × 400 Pixel, Dateigröße: 29 KB)
Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden.
Inhaltsverzeichnis
Beschreibung
BeschreibungFrankfurt population - Prognosen.svg |
Deutsch: Einwohnerentwicklung von Frankfurt mit vier Prognosen |
Quelle | Eigenes Werk |
Urheber | Summer ... hier! (Diskussion) 00:24, 23 October 2017 (UTC) |
Andere Versionen |
Diese Datei wurde von diesem Werk abgeleitet: Frankfurt population.svg |
Lizenz
Diese Datei wird unter der Creative-Commons-Lizenz „CC0 1.0 Verzicht auf das Copyright“ zur Verfügung gestellt. | |
Die Person, die das Werk mit diesem Dokument verbunden hat, übergibt dieses weltweit der Gemeinfreiheit, indem sie alle Urheberrechte und damit verbundenen weiteren Rechte – im Rahmen der jeweils geltenden gesetzlichen Bestimmungen – aufgibt. Das Werk kann – selbst für kommerzielle Zwecke – kopiert, modifiziert und weiterverteilt werden, ohne hierfür um Erlaubnis bitten zu müssen.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Gnuplot script to generate this plot
#!/usr/bin/gnuplot
# gnuplot
# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y" # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator
# Allgemeines zur Ausgabe
unset key # als Standard keine Legende
set style data lines # wird bei 'plot' überschrieben
set style fill transparent solid 0.4 # ebenfalls bei 'plot' überschrieben
set grid #
set border 3 # Bit 1 (unten) + Bit 2 (links)
# Bereiche/Format/etc X-Achse
set xdata time # X-Achse als Zeitachse
set xlabel 'Jahr' # Beschriftung X-Achse
set xlabel offset 0, 0.75 # Schrift etwas höher
set xrange ['01.01.1990':'30.06.2040']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 5
# xtics in Sekunden
# der Beginn der X-Einteilung kann außerhalb xrange
# liegen
set xtics offset 0, 0.5 # Beschritung näher an die X-Achse
set mxtics 5 # Skalenstriche
set xtics nomirror # Nur unten Skalieren
set format x '%Y' # Beschriftungsformat JJJJ
set xtics out # Skal. aussen damit sich nicht von Grafik
# überschr. wird
# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl' offset 2 # Abstand Achse/Label
set yrange [600000:900000]
set ytics 50000
set ytics offset 0.5 # Schrift etwas nach rechts
set ytics nomirror
set decimalsign locale "de_DE.utf8" # Stelle Input und Output auf "," um
# set decimalsign ',' würde nur Output umstellen,
set format y "%'.0f" # Ausgabeformat
set mytics 5
set ytics out # Skal. aussen da sie sonst von Grafik
# überschr. wird
#### Markierungsbalken für die beiden Weltkriege etc.
# Die set-Befehle ggf. auskommentieren
# Attribute für Markierungsbalken
set style rect fillcolor lt -1 fillstyle solid 0.1 noborder
#
# == Dreißigjähriger Krieg
set obj rect from '23.05.1618', graph 0 to '24.10.1648' , graph 1
set label "Dreißigjähriger Krieg" at '30.06.1633', graph 0.8 rotate by +60 center
# == Siebenjähriger Krieg
#set obj rect from '29.08.1756', graph 0 to '21.09.1762' , graph 1
#set label "Siebenjähriger Krieg" at '30.06.1759', graph 0.8 rotate by +60 center
# == Befreiungskriege
#set obj rect from '26.02.1813', graph 0 to '20.11.1815' , graph 1
#set label "Befreiungskriege" at '30.06.1814', graph 0.8 rotate by +60 center
# == 1. Weltkrieg
set obj rect from '28.07.1914', graph 0 to '11.11.1918' , graph 1
set label "1. Weltkrieg" at '30.06.1916', graph 0.9 rotate by +60 center
# == 2. Weltkrieg
set obj rect from '01.09.1939', graph 0 to '04.05.1945' , graph 1
set label "2. Weltkrieg" at '30.06.1942', graph 0.9 rotate by +60 center
# == Dädärä
#set obj rect from '07.10.1949', graph 0 to '03.10.1990' , graph 1
#set label "DDR" at '01.01.1970', graph 0.9 rotate by +60 center
# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir bei UNIX in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
# Windowsbenutzer, die mit Pipes nicht umgehen könnten, sollten hier hier das
# folgende 'set output ...' auskommentieren und den Dateinamen ggf. ersetzen.
# set output 'Frankfurt_population.svg'
set term svg size 800,400 font "Arial,16"
# Die Parameter von 'set term' sind so gewählt, das man in Wikipedia bei einer
# Einbindung [[Datei:Meine_Grafik.svg|mini|400px|Text]] noch Schrift/Details
# erkennen kann.
# Erzeugen der Ausgabe
plot \
'Frankfurt_population.dat' using 1:2 with linespoints linecolor 'dark-blue' linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30,\
'-' using 1:($2) with linespoints linecolor 'dark-green' linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30,\
'-' using 1:($2) with linespoints linecolor 'dark-magenta' linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30,\
'-' using 1:($2) with linespoints linecolor 'dark-red' linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30,\
'-' using 1:($2) with linespoints linecolor 'dark-yellow' linetype 1 linewidth 1.5 pointtype 7 pointsize 0.30
#
# Quelle:
# https://de.wikipedia.org/wiki/Einwohnerentwicklung_von_Frankfurt_am_Main#Bev.C3.B6lkerungsprognose
#
#
# Koordinierte Bevölkerungsvorausberechnung
#
30.06.2010;666920
30.06.2015;679185
30.06.2020;689767
30.06.2030;695738
EOF
#
#
# Prognosen der Stadtverwaltung
#
30.06.2020;764091
30.06.2030;810084
30.06.2040;829773
EOF
#
#
# Prognose der Postbank
#
30.06.2015;708600
30.06.2020;713800
30.06.2025;705100
30.06.2030;686400
30.06.2035;664500
EOF
#
#
# Prognose der Bertelsmann-Stiftung
#
31.12.2012;687560
31.12.2020;752550
31.12.2025;773630
31.12.2030;784920
EOF
Daten
Die Datei "Frankfurt_population.dat", die notwendige CSV Daten enthält, wurde wie in File:Frankfurt_population.svg beschrieben erzeugt. Eventuelle Korrekturen/Ergänzungen der Daten bitte dort vornehmen.
In dieser Datei abgebildete Objekte
Motiv
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
---|---|---|---|---|---|
aktuell | 19:20, 22. Jan. 2018 | 800 × 400 (29 KB) | Summer ... hier! | +Wert 2016 | |
02:24, 23. Okt. 2017 | 800 × 400 (35 KB) | Summer ... hier! | {{Information |Description = {{de|Einwohnerentwicklung von Frankfurt mit vier Prognosen}} |Source = {{own}} |Author = ~~~~ |Date = |Other_versions = {{Derived from|Frankfurt population.svg}} }} == {{int:license-header}} =... |
Dateiverwendung
Keine Seiten verwenden diese Datei.
Metadaten
Diese Datei enthält weitere Informationen (beispielsweise Exif-Metadaten), die in der Regel von der Digitalkamera oder dem verwendeten Scanner stammen. Durch nachträgliche Bearbeitung der Originaldatei können einige Details verändert worden sein.
Kurztitel | Gnuplot |
---|---|
Bildtitel | Produced by GNUPLOT 5.0 patchlevel 3 |
Breite | 800 |
Höhe | 400 |