Zur Beschreibungsseite auf Commons

Datei:Scienta2.jpg

aus Wikipedia, der freien Enzyklopädie
Zur Navigation springen Zur Suche springen

Originaldatei ‎(1.600 × 1.200 Pixel, Dateigröße: 227 KB, MIME-Typ: image/jpeg)

Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden.

Zur Beschreibungsseite auf Commons

 
Diese Grafik wurde mit POV-Ray erstellt.

Beschreibung

Beschreibung
English: path of an electron with 3 different energies in a spherical analyser of a Scienta
Deutsch: Elektronenbahn für Elektronen mit 3 verschiedenen Energien durch einen Kugelanalysator in einem Scienta
Datum
Quelle Eigenes Werk
Urheber Saiht

POVray script

// Schnitt durch ein PhotoelectronSpetroskopie Experiment
// by Matthias Kreier
#version 0.8;
global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.6 diffuse 0.4 }}

#include "colors.inc"  
#include "textures.inc"         

camera {
    ultra_wide_angle
    angle 20
    location <35, 30, -65>
    look_at <6, 13, 0>
}               

//plane { <0, 1, 0>, -1 pigment { color Red } }
//plane { <0, 0, -1>, -50 pigment { color White} }
plane { <0, 1, -1>, -2000 pigment { color LightGray} }

//  ****** Linsensystem zur Fokussierung und Retardierung *******

#declare Linsensystem =
union{ 
 difference{
  union{
    box{<-2.1,3.0,-2.1>,<2.1,3.2,2.1>}
    box{<-2.1,3.4,-2.1>,<2.1,3.6,2.1>}
    box{<-2.1,3.8,-2.1>,<2.1,4.0,2.1>}
    box{<-2.1,6.8,-2.1>,<2.1,7.0,2.1>} 
    pigment { color Blue }   
  }
  cylinder { < 0,2.9,0 > <0,7.1,0> 0.81 pigment { color Silver } }
  cylinder { < 0,2.9,0 > <0,7.1,0> 2 pigment { color Silver } inverse }
 }
 difference{
  union{
    cylinder{ < 0,4.2,0 > <0,4.4,0> 2.1 }
    cylinder{ < 0,4.3,0 > <0,6.5,0> 1.4 }
    cylinder{ < 0,6.4,0 > <0,6.6,0> 2.1 }
    cylinder{ < 0,7.2,0 > <0,7.4,0> 2.1 }
    cylinder{ < 0,7.3,0 > <0,9.9,0> 1.4 }
    cylinder{ < 0,9.8,0 > <0,10,0> 2.1 }
    cylinder{ < 0,10.2,0 > <0,10.4,0> 2.1 }
    cylinder{ < 0,10.3,0 > <0,11.2,0> 1.4 } 
  }
  cylinder { < 0,4.1,0 > <0,11,0> 1.2 pigment { color Silver } }
  cylinder { < 0,10.9,0 > <0,11.3,0> 0.8 pigment { color Silver } }
  cylinder { < 0,4.1,0 > <0,11.3,0> 2 pigment { color Silver } inverse }
 } 
 translate <0,1,0>
}

#declare Kugelanalysator =
union{
 intersection{  // innere Kugel
  difference{
   sphere{<6,14,0>,4.2 texture{Polished_Chrome} }
   sphere{<6,14,0>,4 pigment{color Blue} }
  }
  box{<1,14,-1>,<11,19,5> pigment{color Red}}  
 }
 intersection{  // äußere Kugel
  difference{
   sphere{<6,14,0>,8 pigment{color Blue} }
   sphere{<6,14,0>,7.8 pigment{color Silver} }
  }
  box{<-3,14,-1>,<15,23,9> pigment{color Red}}  
 }
 difference{  // Herzog-Platte 
  cylinder { < 6,12.5,0 > < 6,13,0 > 9 pigment { color LightSteelBlue } }
  cylinder { < 0,12.4,0>,<0,13.1,0>  1.1 pigment{color Silver}}
  cylinder { < 12,12.4,0>,<12,13.1,0>  2.3 }
 } 
 difference{ 
  cylinder { < 12,12.5,0 > < 12,13.8,0 > 2.4 pigment { color Blue } }
  cylinder { < 12,12.4,0> < 12,13.9,0>  2.2 pigment{color Silver}}  
 }  
 intersection{ // Eingangsspalte
  union{
   box {<-2,13.25,-2>,<2,13.35,2> pigment{color Blue} }
   box {<-0.6,13.3,-2>,<0.6,13.75,2> pigment{color Blue} }
  }
  box {<-0.2,13.2,-2.1>,<0.2,14.1,2.1> pigment{color Silver} inverse}
 }
 intersection{ // Eingangsblenden
  union{
   cylinder { < 0,13.85,0 > < 0,13.9,0 > 2 pigment{color Blue} }
   cylinder { < 0,13.1,0 > < 0,13.15,0 > 2 pigment{color Blue} }
  }
  box {<-0.15,13.0,-1>,<0.15,14.1,1> pigment{color Silver} inverse}
 }

}                 

#declare Optik =
union{
  object { Linsensystem
           pigment { color Blue }
         } 
  object { Kugelanalysator }
  rotate<0,0,0>
}
                
#declare Scienta =                
union{ 
 intersection{ // Linsensystem und Analysator entlang x aufgeschnitten  
  object { Optik }
  box{
      <-3,2,0>, <15,23,9> 
      pigment{color Red}
  }
 } 
 intersection{ //aufgeschnitten
  union{
   cylinder{<12,13.3,0> <12,13.8,0> 2 pigment{color CadetBlue}}  // Channelplate
   cylinder{<12,13.0,0> <12,13.2,0> 2 pigment{color Green}}  // Phosphorplatte
  }
  box{ <9,10,0>, <15,15,9> pigment{color rgbf <1,1,1,1>}}
 }
 difference{   // CCD Kamera
   cylinder{<12,9.5,0> <12,11,0> 1.8 pigment{color CadetBlue}}
   cylinder{<12,10 ,0> <12,11.1,0> 1.6 pigment{color Black}}
 }
 cylinder{<12,9.6,0> <12,8,0> 1.4 pigment{color CadetBlue}}
 cylinder{<12,8.1,0> <12,5.5,0> 1.8 pigment{color CadetBlue}}   
 cone{<12,11,0> 1.6 <12,12.95,0> 2 texture{pigment{rgbf<1,1,0.7,0.97>}}
}

// *************    Weg der Elektronen  *********
#declare Elektron1 =
union{
 intersection{      // Normales Elektron, Passenergie
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,0,0>
   translate<6,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }
 intersection{      // Energie kleiner als Epass
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,0,0>
   scale 0.9
   translate<5.4,14,0>    
  }                               
  box{<-2,14,-2>,<13,23,2>}
 }
 intersection{      // Energie größer als Epass
  intersection{
   torus{ 6,0.5 rotate<-3.8,0,0> translate <0,0.46,0> }
   torus{ 6,0.5 rotate< 3.8,0,0> translate <0,-0.46,0> }
   torus{ 6,0.7 translate <-0.67,0,0> }
   torus{ 6,0.7 translate < 0.67,0,0> }
   rotate<90,0,0>
   scale 1.1
   translate<6.6,14,0>    
  }                               
  box{<-2,14,-2>,<15,23,2>}
 }   
 cone { < 0,0,0 >, 0, <0,5.5,0>, 0.6 }
 cone { < 0,5.5,0 >, 0.6, <0,7,0>, 0.4 } 
 cone { < 0,7,0 >, 0.4, <0,8.2,0>,0.03} 
 cone { < 0,8,0 >, 0.03,<0,9,0>, 0.5 }
 cone { < 0,9,0 >, 0.5, <0,10,0>, 0.6 }
 cone { < 0,10,0 >, 0.6, <0,11,0>, 0.5 }
 cone { < 0,11,0 >, 0.5, <0,13.5>, 0.02 }
 cone { < 0,13.5,0>,0.02,<0,14,0>, 0.05 }
 
                                 
// cone { < 0,11,0 >, 0.2, <0,14.1,0>, 0.05 }
// cylinder { < 0,5,0 > <0,11,0> 0.2 } 
// cone { < 0,0,0 >, 0, <0,5,0>, 0.2 }
}

#declare Lichtquelle =
union{
 cylinder{ 
   <-18,18,0> <1,-1,0> 0.5 
   texture{pigment{rgbf<1,1,0.6,0.7>}}
 } 
 difference{
   cylinder{ <-7.5,7.5.0> <-40,40,0> 1.2 }
   cylinder{ <-7.4,7.4.0> <-20,20,0> 0.5 }
   pigment { color LightBlue }
 }
}

#declare Sample = 
union{
 box{<-4.8,-0.5,-4.8>,<4.8,0,4.8> pigment{color RichBlue}}
 cylinder{ < 0,-1,0 > < 0,-2,0> 1 pigment{color Green}}
 }
}

// **********  alles zusammenbauen *********

object { Scienta }

object{ Elektron1 pigment{color Orange} }

object { Lichtquelle } 

object { Sample }
                         

// *********  Lichtquellen  ************

                         

light_source {
    <12, 18, -200>
    color White
}

light_source {
//    <0, 26, -20>
<35, 30, -65>
    color White
} 

light_source {      // Rückseite beleuchten
    <20, 30, 10>
    color White
}

/*                         
light_source { <-60, 28, -200>  color White }

light_source {
//    <0, 26, -20>
//    <30, 30, -45>
    <20, 30, -65>
    color White
} 

light_source { <20, 30, 10> color White } // Rückseite beleuchten
   
    
}  

light_source {      // Kugel innen Licht
    <9, 21, 1.5>
    color White
} 
*/

Lizenz

Public domain Ich, der Urheberrechtsinhaber dieses Werkes, veröffentliche es als gemeinfrei. Dies gilt weltweit.
In manchen Staaten könnte dies rechtlich nicht möglich sein. Sofern dies der Fall ist:
Ich gewähre jedem das bedingungslose Recht, dieses Werk für jedweden Zweck zu nutzen, es sei denn, Bedingungen sind gesetzlich erforderlich.

Kurzbeschreibungen

Ergänze eine einzeilige Erklärung, was diese Datei darstellt.

In dieser Datei abgebildete Objekte

Motiv

Dateiversionen

Klicke auf einen Zeitpunkt, um diese Version zu laden.

Version vomVorschaubildMaßeBenutzerKommentar
aktuell16:50, 15. Jun. 2009Vorschaubild der Version vom 16:50, 15. Jun. 20091.600 × 1.200 (227 KB)Saiht{{Information |Description={{en|1=path of an electron with 3 different energies in a spherical analyser of a Scienta}} {{de|1=Elektronenbahn für Elektronen mit 3 verschiedenen Energien durch einen Kugelanalysator in einem Scienta}} |Source=Own work by up

Die folgende Seite verwendet diese Datei:

Metadaten

Diese Datei enthält weitere Informationen (beispielsweise Exif-Metadaten), die in der Regel von der Digitalkamera oder dem verwendeten Scanner stammen. Durch nachträgliche Bearbeitung der Originaldatei können einige Details verändert worden sein.

Abgerufen von „https://de.wikipedia.org/wiki/Datei:Scienta2.jpg“